Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

Key.addListener()

Доступность

Flash Player 6.

Синтаксис

Key.addListener (newListener:Object) : Void

Параметры

newListener Объект с методами onKeyDown и onKeyUp.

Возвращает

Ничего.

Описание

Метод; регистрирует объект в списке листнеров (слушателей событий), получающих оповещения о событиях onKeyDown и onKeyUp. При нажатии или отпускании клавиши, вне зависимость от того, какой элемент ролика имеет клавиатурный фокус, у все листнеров, добавленных при помощи метода addListener(), вызывается метод onKeyDown или onKeyUp, соответственно. Слушателями клавиатурных событий могут быть несколько объектов одновременно. Если листнер newListener уже присутствует в списке, изменений не происходит.

Пример

В следующем примере создается новый листнер и для него определяются функции onKeyDown и onKeyUp. В последней строке addListener() регистрирует объект в списке листнеров класса Key, оповещая их о клавиатурных событиях.

var myListener:Object = new Object();
myListener.onKeyDown = function () {
  trace ("Вы нажали клавишу.");
}
myListener.onKeyUp = function () {
  trace ("Вы отпустили клавишу.");
}
Key.addListener(myListener);

В следующем примере клавиатурной комбинации Control+7 ставится в соответствие кнопка my_btn, выводящая информацию о комбинации клавиш (смотри _accProps). В данном примере при нажатии пользователем Control+7, функция myOnPress выводит текст Привет на панель Output.

function myOnPress() {
  trace("Привет");
}
function myOnKeyDown() {
  // 55 есть код клавиши 7
  if (Key.isDown(Key.CONTROL) && Key.getCode() == 55) {
    Selection.setFocus(my_btn);
    my_btn.onPress();
  }
}
var myListener:Object = new Object();
myListener.onKeyDown = myOnKeyDown;
Key.addListener(myListener);
my_btn.onPress = myOnPress;
my_btn._accProps.shortcut = "Ctrl+7";
Accessibility.updateProperties();

См. также

Key.getCode(), Key.isDown(), Key.onKeyDown, Key.onKeyUp, Key.removeListener()

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление